DUA3:<000000>KITINSTAL.COM;5
 
$ !
$ !
$ !                       K I T I N S T A L . C O M 
$ !
$ !                       COPYRIGHT (C) 1986, 1987, 1988 BY
$ !                    DIGITAL EQUIPMENT CORPORATION, MAYNARD
$ !                     MASSACHUSETTS.  ALL RIGHTS RESERVED.
$ !
$ !  THIS SOFTWARE IS FURNISHED UNDER A LICENSE AND MAY BE USED AND COPIED
$ !  ONLY IN ACCORDANCE WITH THE TERMS OF SUCH LICENSE AND WITH THE INCLUSION
$ !  OF THE ABOVE COPYRIGHT NOTICE.  THIS SOFTWARE OR ANY OTHER COPIES
$ !  THEREOF MAY NOT BE PROVIDED OR OTHERWISE MADE AVAILABLE TO ANY OTHER
$ !  PERSON.  NO TITLE TO AND OWNERSHIP OF THE SOFTWARE IS HEREBY TRANSFERRED.
$ !
$ !  THE INFORMATION IN THIS SOFTWARE IS SUBJECT TO CHANGE WITHOUT NOTICE AND
$ !  SHOULD NOT BE CONSTRUED AS A COMMITMENT BY DIGITAL EQUIPMENT CORPORATION.
$ !
$ !  DIGITAL ASSUMES NO RESPONSIBILITY FOR THE USE OR RELIABILITY OF ITS
$ !  SOFTWARE ON EQUIPMENT THAT IS NOT SUPPLIED BY DIGITAL.
$ !
$ !
$ !**********************************************************************
$ !*                                                                    *
$ !*            VAX FORTRAN V4  FORHELP V4 Installation                 *
$ !*                     Procedure for VMSINSTALL                       *
$ !*                                                                    *
$ !**********************************************************************
$ !
$ !     The following are required by VMSINSTALL....
$ !
$       ON      CONTROL_Y -
        THEN    VMI$CALLBACK CONTROL_Y
$       ON      WARNING -
        THEN    GOTO    FORT_INSTALL_WARNING
$ !
$ !     If DEBUGging, set verify on.
$ !
$       FORT$VERIFY = F$VERIFY (P2)
$ !
$ !     Check the parameters for VMSINSTALL functions....
$ !
$       IF      P1 .EQS. "VMI$_INSTALL" -
        THEN    GOTO    FORT_INSTALL
$       FORT$VERIFY = F$VERIFY (FORT$VERIFY)
$       EXIT    VMI$_UNSUPPORTED
$ !
$ !**********************************************************************
$ !*    Install FORTRAN V4 FORHELP V4
$ !**********************************************************************
$ !
$ FORT_INSTALL:
$       TYPE    SYS$INPUT:

        +-------------------------------------------------------+
        |          Installation of VAX FORTRAN V4               |
        |                     FORTRAN HELP                      |
        +-------------------------------------------------------+

$ !
$ !**********************************************************************
$ !*    Must be VMS V4.0 or later...
$ !**********************************************************************
$ !
$ CHECK_VMS_VERSION:
$       ON ERROR THEN GOTO BAD_VMS_VERSION              ! Version check may blow up on pre-V4 system
$       VMI$REQUIRED == "040"
$       FORTSTR$VMS == 0
$       !
$       ! grab RELASED, UPGRADE, or UPDATE keyword
$       VMI_TYPE= F$ELEMENT(0,",",VMI$VMS_VERSION)
$       VMI_TYPE = F$ELEMENT(0," ",VMI_TYPE)    ! Ignore FT if there
$       !
$       ! grab VMS version number       
$       VMI_VERSION = F$ELEMENT(1,",",VMI$VMS_VERSION)
$       !
$       ! if UPGRADE version number is "meaningless"
$       IF VMI_TYPE .NES. "UPGRADE" THEN GOTO CONTINUE_VERSION_CHECK
$       VMI$CALLBACK MESSAGE I UPGRDVMS -
           "Assuming VMS version is V4.0 or greater"
$       GOTO CHECK_VMS_VERSION_END
$ CONTINUE_VERSION_CHECK:
$       IF F$EXTR(0,3,VMI_VERSION) .GES. F$EXTR(0,3,VMI$REQUIRED) -
         THEN FORTSTR$VMS == 1
$       IF FORTSTR$VMS THEN GOTO CHECK_VMS_VERSION_END
$ BAD_VMS_VERSION:
$       VMI$CALLBACK MESSAGE E BADVMS1 -
           "This kit requires VMS V4.0 (or later) for correct installation."
$       VMI$CALLBACK MESSAGE E BADVMS2 -
           "Please install VMS V4.0 (or later) before installing VAX FORTRAN."
$       $STATUS = VMI$_FAILURE
$       GOTO FORT_INSTALL_WARNING
$ !
$ CHECK_VMS_VERSION_END:
$       ON ERROR THEN GOTO FORT_INSTALL_WARNING ! back to normal error mode
$ !
$ !     Purging files...
$ !
$       VMI$CALLBACK    SET -
                        PURGE -
                        NO
$ !
$ !     No IVP for FORHELP....
$ !
$       VMI$CALLBACK    SET -
                        IVP -
                        NO
$ !
$ !     What about HELP FORTRAN ?
$ !
$       TYPE    SYS$INPUT:

        This  kit  contains two separate  HELP  files,  a  large
        version (approximately 600 blocks) including information
        on FORTRAN  language  features,  and  a  smaller version
        (approximately 100 blocks)  describing only the  FORTRAN
        command.  Both versions contain on-line release notes.

$       VMI$CALLBACK    ASK -
                        FORT$LARGE_HELP -
                        "Do you want to install the larger version of FORTRAN HELP" -
                        YES -
                        B
$ !
$ !     'Install' FORHELPS.HLP or FORHELPL.HLP
$ !
$       IF      FORT$LARGE_HELP -
        THEN    GOTO    FORT_LARGE_HELP
$ !
$ !     Need at least 800 blocks....
$ !
$       VMI$CALLBACK    CHECK_NET_UTILIZATION -
                        FORT$ENOUGH_ROOM -
                        800
$       IF      .NOT. FORT$ENOUGH_ROOM -
        THEN    VMI$CALLBACK    MESSAGE -
                                E -
                                NOROOM -
                                "This kit requires at least 800 free disk blocks."
$       IF      .NOT. FORT$ENOUGH_ROOM -
        THEN    EXIT    VMI$_FAILURE
$ !
$ !     Extract the small help...
$ !
$       LIBRARY /EXTRACT=(*) -
                /OUTPUT=VMI$KWD:FORHELPS.HLP -
                VMI$KWD:FORHELPS.TLB
$ !
$ !     ... and install it.
$ !
$       VMI$CALLBACK    PROVIDE_DCL_HELP -
                        FORHELPS.HLP
$       GOTO    FORT_HELP_DONE
$ FORT_LARGE_HELP:
$ !
$ !     Need at least 2000 blocks....
$ !
$       VMI$CALLBACK    CHECK_NET_UTILIZATION -
                        FORT$ENOUGH_ROOM -
                        2000
$       IF      .NOT. FORT$ENOUGH_ROOM -
        THEN    VMI$CALLBACK    MESSAGE -
                                E -
                                NOROOM -
                                "This kit requires at least 2000 free disk blocks."
$       IF      .NOT. FORT$ENOUGH_ROOM -
        THEN    EXIT    VMI$_FAILURE
$ !
$ !     Extract the small help, calling it the large help...
$ !
$       LIBRARY /EXTRACT=(*) -
                /OUTPUT=VMI$KWD:FORHELPL.HLP -
                VMI$KWD:FORHELPS.TLB
$ !
$ !     ... and then the medium help...
$ !
$       LIBRARY /EXTRACT=(*) -
                /OUTPUT=VMI$KWD:FORHELPM.HLP -
                VMI$KWD:FORHELPM.TLB
$ !
$ !     ... and concatenate the two...
$ !
$       APPEND  VMI$KWD:FORHELPM.HLP -
                VMI$KWD:FORHELPL.HLP
$ !
$ !     ... and finally install the resulting large help.
$ !
$       VMI$CALLBACK    PROVIDE_DCL_HELP -
                        FORHELPL.HLP
$ FORT_HELP_DONE:
$       TYPE    SYS$INPUT:

        Your  VMS  system  will now be updated  to  include  the
        following new and modified file(s):

        SYS$HELP:HELPLIB.HLB            [modified]

$ !
$ !     All done, leave now....
$ !
        FORT$VERIFY = F$VERIFY (FORT$VERIFY)
$       EXIT    VMI$_SUCCESS
$ !
$ !     Installation errors....
$ !
$ FORT_INSTALL_WARNING:
$       FORT$STATUS = $STATUS
$       FORT$VERIFY = F$VERIFY (FORT$VERIFY)
$       EXIT    FORT$STATUS

